##############################
 ##############################
 ##                          ##
 ##  mfToon v0.42 by mf ^^;  ##
 ##                          ##
 ## I would claim copyright, ##
 ## but as I do not give my  ##
 ## real identity, I can't.  ##
 ## So as netizen to net-    ##
 ## izen, I ask you, please  ##
 ## don't do lame stuff      ##
 ## with my script, like     ##
 ## claiming you made it.    ##
 ## Thank you.               ##
 ##                          ##
 ##############################
 ##############################
               ##
               ##
################################
################################
##                            ##
## Usage:                     ##
##                            ##
## Import("mfToon-v0.42.avs") ##
## mfToon()                   ##
##                            ##
################################
################################

####
##
## You can now change the relative sharpness horizontally and vertically respectively.
## Might be useful for sources where you want to preserve blurriness horizontally or
## vertically. Very small change, but it could speed up processing slightly. Note
## that mfToon(ssw=4, ssh=4, hsharp=4, vsharp=4) is virtually identical to
## mfToon(ssw=1, ssh=1, xstren=0, xthresh=0), and only slower.
## There's also new debug stuff to play with when bored.
##

function mfToon(clip orig, int "twidth", int "theight", int "ssw", int "ssh", int "xstren", \
int "xthresh", bool "cwarp", bool "sharpen", int "strength", float "wdepth", int "wblur",   \
float "wthresh", float "ublur", int "ustren", int "urange", float "uboost", int "dstren",   \
int "drange", float "dboost", int "dlimit", int "hsharp", int "vsharp", bool "debug",       \
bool "doutput", string "dclip", bool "show", int "scolor") {

# normal params

strength = Default(strength, 255)	 # line darkening strength, 0-255
sharpen  = Default(sharpen, true)	 # sharpening on/off
cwarp    = Default(cwarp, true)		 # chroma warp on/off
cwarp2   = cwarp ? 1 : 0
wdepth   = Default(wdepth, 16.0)	 # warping depth, ?-?
wblur    = Default(wblur, 1)		 # warping blur level, ?-?
wthresh  = Default(wthresh, 0.5)	 # warping threshold, 0.0-1.0
ssw      = Default(ssw, 4)     		 # supersample factor horizontally, 0-inf
ssh      = Default(ssh, 4)		 # supersample factor vertically, 0-inf
hsharp   = Default(hsharp, 1)		 # horizontal sharpness modifier, 1-ssh
vsharp   = Default(vsharp, 1)		 # vertical sharpness modifier, 1-ssw
twidth 	 = Default(twidth, orig.width)	 # target width (useful for cropping), 0-inf
theight	 = Default(theight, orig.height) # target height (useful for cropping), 0-inf
show     = Default(show, false)		 # show which lines are being darkened
scolor	 = Default(scolor, $FF00FF)	 # which color to show lines in


# advanced params

xstren   = Default(xstren, 255)   	 # xsharpening strength, 0-255
xthresh  = Default(xthresh, 255)  	 # xsharpening threshold, 0-255
ublur    = Default(ublur, 1.58)   	 # unsharp mask blur level, 0.0-1.58
ustren   = Default(ustren, 255)   	 # unsharp mask strength, 0-255
urange   = Default(urange, 115)   	 # unsharp mask range, 0-255
uboost   = Default(uboost, 1.0)   	 # unsharp mask boost, 0.0-10.0
dstren   = Default(dstren, 255)   	 # detail strength, 0-255
drange   = Default(drange, 64)    	 # detail range, 0-255
dboost   = Default(dboost, 1.0)   	 # detail boost, 0.1-10.0
dlimit   = Default(dlimit, 30)    	 # detail limiter, 0-255
debug    = Default(debug, false)	 # debug mode on/off
doutput  = Default(doutput, true)	 # print debug info on processed image
dclip    = Default(dclip, "rclip1")	 # which stage of the processing to show

hsharp2  = twidth  * hsharp
vsharp2  = theight * vsharp
ssw2     = twidth  * ssw
ssh2     = theight * ssh
sharpen2 = show    ? false : sharpen

mask = orig.Blur(ublur).Blur(ublur).Blur(ublur).Blur(ublur).Blur(ublur).Blur(ublur)
sharp = Subtract(orig, mask).ConvertToYUY2()
origyuy = orig.ConvertToYUY2()
sharp2 = origyuy.MergeLuma(Layer(origyuy, sharp, "mul", 255) \
.Levels(0, uboost, urange, 0, 255)).ConvertToRGB32() 
origrgb = origyuy.ConvertToRGB32()
greymask = origrgb.Greyscale().Levels(0, 1, 255, 255, 0)

detailmaskpre = orig.EdgeMask(0, "sobel").Tweak(0.0, 1.0, drange, 1.0) \
.Levels(60, dboost, 255, 0, 255).Levels(0, dboost, dlimit, 255, 0).GreyScale().ConvertToYUY2()
detailmaskpre2 = Layer(detailmaskpre, detailmaskpre, "mul", 255).Blur(1.0)
detailmask = Layer(detailmaskpre2, detailmaskpre2, "mul", 255).Levels(0, 1.0, 189, 0, 255) \
.ConvertToYV12().Inflate().ConvertToRGB32()
maskeddetail = Mask(detailmask, greymask)
white = BlankClip(greymask, color=$FFFFFF)
linemask = Layer(white, maskeddetail, "add", dstren).Levels(0, 1, 255, 255, 0)

color = BlankClip(origrgb, color=scolor)
sharp3 = show ? color : sharp2
maskedsharp = Mask(sharp3, linemask)
dark = Layer(origrgb.Greyscale(), maskedsharp, "add", strength)
darkyv12 = dark.ConvertToYV12()
darkmerged = orig.MergeLuma(darkyv12) 
finaldark = show ? darkyv12 : darkmerged

semifinal = darkyv12.PointResize(hsharp2, vsharp2).BicubicResize(ssw2, ssh2, 0, 0.75) \
.XSharpen(xstren, xthresh).BicubicResize(twidth, theight, 0, 0.75)

final=orig.BicubicResize(twidth, theight, 0, 0.75).MergeLuma(semifinal).aWarpSharp(cm=cwarp2, depth=wdepth, \
blurlevel=wblur, thresh=wthresh)

      rclip1  = sharpen2 ?   final    : finaldark
Eval("dclip1  = doutput  ? "+dclip+"  : orig")

dstring1 = "mfToon v0.42 by mf - Debug mode ;p"
dstring2 = "Pointsized: " + String(hsharp2) + "x" + String(vsharp2)
dstring3 = "Bicubicsized: " + String(ssw2) + "x" + String(ssh2)
dstring4 = "Outputsize: " + String(twidth) + "x" + String(theight)
dstring5 = "Debug image: " + dclip
clipstring = sharpen2 ? "final" : "finaldark"
dstring6 = "Output image: " + clipstring

      dclip2  = dclip1.Subtitle(dstring1).Subtitle(dstring2, y=33).Subtitle(dstring3, y=48) \
                .Subtitle(dstring4, y=63).Subtitle(dstring5, y=78).Subtitle(dstring6, y=93)
      rclip2  = debug   ?   dclip2   : rclip1

return rclip2
}